Curso de Software de Ventas Parte 27, Ventana de Ventas Parte 2

Ya comenzando con el código de la ventana de ventas lo primero es inicializar los controles, como son la fecha, el termino de la factura y los días.

Suscribete a mi canal

Para esto creamos un Sub Procedimiento llamado Inicial:

Sub Inicial()
    txtFechaApro.Text = Format(Date, "dd/mm/yyyy")
    cmdTipoFact.ListIndex = 0
    txtDias.Text = 0
    
End Sub

En caso de que el termino de la factura escogido es Contado o Crédito el código en el evento clic del control ComboBox es el siguiente:

Private Sub cmdTipoFact_Click()
    If cmdTipoFact.ListIndex = 0 Then 'contado
       txtDias.Text = 0
       txtDias.Enabled = False
       CodigoCliente = 1
    Else  'Crédito
       txtNombre_Cli.Enabled = False
       txtTelefono_cli.Enabled = False
       txtDias.Text = 30
       txtDias.Enabled = True
    End If
End Sub

En la base de datos debemos tener un cliente predeterminado que es para las ventas de contado, este cliente no se puede modificar siempre debe aparecer en este caso va a tener el id = 1

Lo siguiente es hacer el Buscar Cliente para eso se crea una variable global en el modulo Conexion:

Global glob_FormularioSolicBuscarCli As String

Esta variable sera usada para pasar el nombre del formulario que llama a la Ventana de Buscar Cliente.

En el evento clic del botón buscar cliente del formulario de ventas va el siguiente Código:

Private Sub cmdBuscarCliente_Click()
    glob_FormularioSolicBuscarCli = Me.Name
    frmBuscarCliente.Show
End Sub

Se modifico el Procedimiento de BuscarClientes en la ventana de Buscar Cliente para agregar el campo cupo:

Sub BuscarClientes()
    Dim Sql As String
    Dim Filtro As String
    Dim Columnas As Integer
    'IdUsuario,usuario,password_us,identificacion,nombres_apellidos,IdNivelUsuario
    Tipo = cmdTipoBusqueda.ListIndex
    Filtro = ""
    Select Case Tipo
           Case 0:
                Filtro = " NombreApellidos_cli like '%" & txtFiltro.Text & "%' "
           Case 1:
                Filtro = " Identificacion_cli like '%" & txtFiltro.Text & "%' "
           Case 2:
                Filtro = " IdCliente like '%" & txtFiltro.Text & "%' "
    End Select
    Sql = "Select IdCliente, NombreApellidos_cli, Identificacion_cli, Telefonos_cli, CupoAutorizado_cli From tblClientes Where " & Filtro
    Columnas = 4
    Call LlenarGrid(msGrid, Sql, Columnas)
    
    
    msGrid.ColWidth(0) = 0
    msGrid.ColWidth(1) = 1100
    msGrid.ColWidth(2) = 3500
    msGrid.ColWidth(3) = 1800
    msGrid.ColWidth(4) = 1800
    msGrid.ColWidth(5) = 0

    msGrid.TextMatrix(0, 1) = "ID"
    msGrid.TextMatrix(0, 2) = "Razon Social / Nombre"
    msGrid.TextMatrix(0, 3) = "Identificación"
    msGrid.TextMatrix(0, 4) = "Teléfonos"
    msGrid.TextMatrix(0, 5) = "Cupo"
    
End Sub

En la ventana de Buscar Cliente el código del botón Seleccionar debe quedar de la siguiente manera:

Private Sub cmdSeleccionar_Click()
    Dim Codigo As Long
    Dim Identifi As String
    Dim Nombre As String
    Dim Telefono As String
    Dim Cupo  As Currency
    
    'If msGrid.Row > 0 Then
    '   IdTipoUsuario = msGrid.TextMatrix(msGrid.Row, 1)
    '   Call frmAdministacionUsuarios.LlenarUsuario(IdTipoUsuario)
    '   Unload Me
    'End If
    Codigo = msGrid.TextMatrix(msGrid.Row, 1)
    If Codigo <> 0 Then
        If glob_FormularioSolicBuscarCli = "frmVentas" Then
           Nombre = msGrid.TextMatrix(msGrid.Row, 2)
           Identifi = msGrid.TextMatrix(msGrid.Row, 3)
           Telefono = msGrid.TextMatrix(msGrid.Row, 4)
           Cupo = msGrid.TextMatrix(msGrid.Row, 5)
           Call frmVentas.SeleccionarCliente(Codigo, Identifi, Nombre, Telefono, Cupo)
           Unload Me
        End If
    End If
    
End Sub

En el código anterior llamamos a un Sub Procedimiento llamado SeleccionarCliente en la ventana de ventas el código es el siguiente:

Sub SeleccionarCliente(Codigo As Long, Indentifi As String, Nombre As String, Telefono As String, Cupo As Currency)
    CodigoCliente = Codigo
    txtIdentificacion_Cli.Text = Indentifi
    txtNombre_Cli.Text = Nombre
    txtTelefono_cli.Text = Telefono
    txtCuposA.Text = Cupo
End Sub